Scripts

[1Cap]

I just discovered the wheel.
Using the command / dbgtiles 1.
Just make a script and/or use bind.
Example: When you're with the flag and defending, you can give the command /dbgtiles1 and see through the wall if the kevlar, helmet, ammunition, akimbo, are in place. Then you pick up and return.
You can see through the wall if your enemy took something without going there.
- Does it change the gameplay? -
we will divide the Ac on two levels:
1) Script clan/players pró
2) no-script clan/player pró

[#M|A#Wolf]

...

For me it just works for helmets. It literally picks off every single mapmodel in the map as well, and it's incredibly annoying.

[Luc@s]

I just discovered the wheel.
Using the command / dbgtiles 1.

No relation with damage scripts.
dbgtiles was obviously introduced for debugging purposes only and using it to gain an advantage /could/ be considered as cheating.

By the way, this command was removed from the game a few months ago.

[BarricadeX75]

Using the command / dbgtiles 1.
Just make a script and/or use bind.

Yeah sure, binding a command to a key makes you a hardcore scripter.

[vern]

Post your scripts here (with a short explanation what it does).

"Credit goes to original autor"

To use this scripts copy&paste them in your "autoexec.cfg" you can find it in the "config"-section of you Assaultcube.


1. Quick knife script:
[cubescript]
alias quickknife [
if (!= (curweapon) 6) [melee]
attack
onrelease [ sleep 1 [ if (= (curweapon) 0) [weapon (prevweapon)] ] ]
]
bind Q quickknife
[/cubescript]
To activate this script you have to press and hold "q" ingame. You will draw your knife and attack. When you stop pressing "q" you'll automaticly change back to your previous weapon.


2. Knifeattack script:
[cubescript]alias knifeattack [
if (= (currentprimary) (curweapon)) [
weapon 0
] [
primary
]
]
bind Q knifeattack[/cubescript]
This script will make you change to kinfe/primary weapon everytime you press "q"


3. Zoom script by stef:
[cubescript]//zoom script by stef with fog 1024 trick added, a must for a sniper
alias adjustsens [
scopefov 40
scopesensscale = (divf $scopefov $fov)
]
alias altaction_4 [ alias oldfog $fog;fog 1024
adjustsens; domodifier 1; zoom 1;
onrelease [ zoom 0; adjustsens; fog $oldfog ]
]
alias delta_game_1 [
if (= $arg1 1) [
if (> $scopefov 5) [scopefov (- $scopefov 5) ]
][
if (< $scopefov 60) [scopefov (+ $scopefov 5) ]
];
sensitivity (divf (*f (*f $oldsens $scopesensscale) $scopefov) 40)
][/cubescript]
With this script you can zoom with your sniper. Just scroll with your scrollwheel while you scope.


4. Out of ammo script:
[cubescript]// out of ammo -> pistol
alias noprimammo [
if (= curweapon [currentprimary]) [sleep 100 [if (= (magcontent (currentprimary)) 0)[ weapon 1]]]]
bind MOUSE1 [attack;noprimammo][/cubescript]
With this script you will automaticly change to the pistol when your primary weapon is out of ammo. (To use it with the SMG/AR you may have to set "autoreload" off or press the mousebutton again when you are out of ammo)


5. Teamchange script:
[cubescript]alias swapteams [sleep 100 [autoteam 0]; sleep 200 [forceteam 0]; sleep 300 [forceteam 1]; sleep 400 [forceteam 2]; sleep 500 [forceteam 3]; sleep 600 [forceteam 4]; sleep 700 [forceteam 5]; sleep 800 [forceteam 6]; sleep 900 [forceteam 7]; sleep 1000 [forceteam 8]; sleep 1100 [forceteam 9]; sleep 1200 [forceteam 10]; sleep 1300 [forceteam 11]; sleep 1400 [forceteam 12]; sleep 1500 [forceteam 13]; sleep 1600 [autoteam 1]][/cubescript]
You need to be admin for this script.
When you type "/swapteams" ingame (or bind it to a key/in a menu) every player will change the team.
(For some reason it doesn't work properly for me. If the author of this script could have a look at this and tell me if it's wrong or something, I'd be very happy :) )


6. "Get rid of suckers" - script aka force script
[cubescript]alias force_cn -1;
alias forceloop_o [
callvote 5 $force_cn;
sleep 5000 forceloop;
]
alias forceloop [];
alias start_force [
alias forceloop $forceloop_o;
forceloop;
]
alias stop_force [
alias forceloop [];
]
alias force [
if (< $numargs 1) [
echo "Error: FORCE needs a ClientNumber!";
] [
alias force_cn $arg1;
start_force;
]
]
bind F8 [ stop_force;echo "Force Stopped!" ]
[/cubescript]
You need to be admin for this script.
When you type "/force cn" ingame the player with the choosen cn will get changed to the enemy team ever 5 second or something, till you press F8 or he leaves.
This is a nice altanative to kick/ban :)

Mod Edit: Upgraded [noparse][code] tags to [cubescript][/noparse] tags

Cmon autor's, right a damn script. This was at one time a scripts thread... I'll try...

[cubescript]Assaultcube = [ yumad ] [ yunoob ]
if yunoob = Assaultcube [ Bind Alt + F4 ]
if yumad = jamz [ Auto Perma Ban ]
Format getnoobalais [ yumad ] [ yunoob ] [ jamz ]
if 3/8/2013 [ RELEASE A FRIGGIN NEW VERSIONS AND GIVE US ALL SOMETHING TO REALLY DISCUSS ] [/cubescript]

I think I win, you may need to compile the compiler to get my scripts to work properly. wp gg

[#M|A#Wolf]

3/8/2013

You must be American.

[jamz]

No, he's happy to wait until the 3rd of August.

[InitialSAW]

3/8/2013

You must be American.

Is this bad? :P

[CharlyMurphie]

If you know some people fromr Boston its harrrible J/K :P

[BarricadeX75]

[SELECT ALL] Code:

//By BarricadeX75/Frenzy, with help from Bukz :D

fcchrono = 0
startedcounting = 0
alias fccincrement [if (= 0 $stplp) [+= fcchrono 1; sleep 100 [fccincrement]]]

add2conloop [

        if (= 5 $gamemode) [

            if_conline_has (concatword (c 2) "you have the enemy flag") [
                stplp = 0
                if (= 0 $startedcounting) [fccincrement]
                sleep 20 [startedcounting = 1]
                echo (c 3) Chrono started!
            ]

            if_conline_has (concatword (c 2) "you scored") [
                fctime = (divf $fcchrono 10)
                echo (format "%1Time taken to score: %2%3 %1seconds" (c 7) (c 3) $fctime)
                sleep 20 [fcchrono = 0; startedcounting = 0; stplp = 1]
            ]

            if_conline_has (concatword (c 2) "you dropped the flag") [
                echo (c 3) You failed at scoring
                fcchrono = 0
                startedcounting = 0
                stplp = 1
            ]

            if_conline_has (concatword (c 2) "you lost the flag") [
                echo (c 3) You failed at scoring
                fcchrono = 0
                startedcounting = 0
                stplp = 1
            ]

        ]

    ]

This script will display the amount of time it took you to score each time you score a flag in CTF. (It starts counting as soon as you pick up the enemy flag)
Note that the chronometer will reset if you die or drop the flag by yourself.
This script requires tools.cfg :P

EDIT: updated with the new color tags :P

[PhaNtom]

[cubescript]
//By BarricadeX75/Frenzy, with help from Bukz :D

fcchrono = 0
startedcounting = 0
alias fccincrement [if (= 0 $stplp) [+= fcchrono 1; sleep 100 [fccincrement]]]

add2conloop [

if (= 5 $gamemode) [

if_conline_has "2you have the enemy flag" [
stplp = 0
if (= 0 $startedcounting) [fccincrement]
sleep 20 [startedcounting = 1]
echo "3Chrono started!"
]

if_conline_has "2you scored" [
fctime = (divf $fcchrono 10)
echo (concatword "7Time taken to score:3 " $fctime " 7seconds")
sleep 20 [fcchrono = 0; startedcounting = 0; stplp = 1]
]

if_conline_has "2you dropped the flag" [
echo "3You failed at scoring"
fcchrono = 0
startedcounting = 0
stplp = 1
]

if_conline_has "2you lost the flag" [
echo "3You failed at scoring"
fcchrono = 0
startedcounting = 0
stplp = 1
]

]

]
[/cubescript]

This script will display the amount of time it took you to score each time you score a flag in CTF. (It starts counting as soon as you pick up the enemy flag)
Note that the chronometer will reset if you die or drop the flag by yourself.
This script requires tools.cfg :P

We can't see that binary character ;) Edit your post to use this:

[cubescript]
//By BarricadeX75/Frenzy, with help from Bukz :D

fcchrono = 0
startedcounting = 0
alias fccincrement [if (= 0 $stplp) [+= fcchrono 1; sleep 100 [fccincrement]]]

add2conloop [

if (= 5 $gamemode) [

if_conline_has concatword (c 2) "you have the enemy flag" [
stplp = 0
if (= 0 $startedcounting) [fccincrement]
sleep 20 [startedcounting = 1]
echo concatword (c 3) "Chrono started!"
]

if_conline_has concatword (c 2) "you scored" [
fctime = (divf $fcchrono 10)
echo (concatword (c 7) "Time taken to score: " (c 3) $fctime (c 7) "seconds")
sleep 20 [fcchrono = 0; startedcounting = 0; stplp = 1]
]

if_conline_has concatword (c 2) "you dropped the flag" [
echo concatword (c 3) "You failed at scoring"
fcchrono = 0
startedcounting = 0
stplp = 1
]

if_conline_has concatword (c 2) "you lost the flag" [
echo concatword (c 3) "You failed at scoring"
fcchrono = 0
startedcounting = 0
stplp = 1
]

]

]
[/cubescript]

That should work.

[Bukz]

Almost @ PhaNtom, you need to wrap parenthesis around the concatword statements though.

[cubescript]if_conline_has (concatword (c 2) "you lost the flag") [[/cubescript]

[BarricadeX75]

[cubescript]
//By BarricadeX75/Frenzy, with help from Bukz :D

fcchrono = 0
startedcounting = 0
alias fccincrement [if (= 0 $stplp) [+= fcchrono 1; sleep 100 [fccincrement]]]

add2conloop [

if (= 5 $gamemode) [

if_conline_has "2you have the enemy flag" [
stplp = 0
if (= 0 $startedcounting) [fccincrement]
sleep 20 [startedcounting = 1]
echo "3Chrono started!"
]

if_conline_has "2you scored" [
fctime = (divf $fcchrono 10)
echo (concatword "7Time taken to score:3 " $fctime " 7seconds")
sleep 20 [fcchrono = 0; startedcounting = 0; stplp = 1]
]

if_conline_has "2you dropped the flag" [
echo "3You failed at scoring"
fcchrono = 0
startedcounting = 0
stplp = 1
]

if_conline_has "2you lost the flag" [
echo "3You failed at scoring"
fcchrono = 0
startedcounting = 0
stplp = 1
]

]

]
[/cubescript]

This script will display the amount of time it took you to score each time you score a flag in CTF. (It starts counting as soon as you pick up the enemy flag)
Note that the chronometer will reset if you die or drop the flag by yourself.
This script requires tools.cfg :P

We can't see that binary character ;)

Try copy/pasting this script somewhere else and it'll be here ;)

EDIT: but anyway, I'm updating it using those tags right now :P

[RandumKiwi]

Three new scripts from myself: http://ac-akimbo.net/search.php?action=r...a6e863e08e

[bballn45]

Maybe a script where if i click say mouse button 4, my automatic gunfire would change to three round burst fire. If anyone can please do this, it would me much appreciated.

[PhaNtom]

@bballn45:

[cubescript]burston = 0

bind MOUSE4 [
if (= $burston 0) [
echo "Mode: burst"
burstshots (curweapon) 3
burston = 1
] [
echo "Mode: automatic"
burstshots (curweapon) 0
burston = 0
]
][/cubescript]

[Speedbomb00]

7. AFK Script

[SELECT ALL] Code:

//AFK Script
//by CiD
//TODO: make a settings menu
//User Settings
//This is what will be added to your name when you are AFK.
afkstr = "|afk"

//If set to 1, it will display a message to other players when you go AFK. Set to 0 to disable.
afkshowmessage = 1

//This will be placed after your name and sent to other players.
afkmessage = "is no longer available."

//This is how long (in seconds) the script will wait if you are idle before changeing you to AFK.
timeuntilafk = 20

//DO NOT EDIT BELOW HERE
curafk = 0
afktime = 0
alias afk [
if $arg1 [
if (= $curafk 0) [
oldname = $curname
name (concatword $oldname $afkstr)
curafk = 1
echo "You are now set to: AFK"
if $afkshowmessage [say (concat "AFKScript:" $oldname $afkmessage )]
]
] [
if $curafk [
name $oldname
curafk = 0
echo "You are now set to: ONLINE"
]
]
]
alias notafk [
if (= $afktime 0) [afkcheck]
afktime = 0
if (= $curafk 1) [afk 0]
]
alias afkcheck [
afktime = (+ $afktime 5)
if (= 2 (+ (> $afktime (* $timeuntilafk 1000)) (= $curafk 0))) [afk 1]
sleep 5 afkcheck
]
bind w [forward;notafk]
bind a [left;notafk]
bind s [backward;notafk]
bind d [right;notafk]
//END of AFK Script

It automatically changes your nickname from "nickname" to "afk|nickname" after some inactivity period.

This didn't work completely for me, so I wrote a modified version. Credits are in the script. I feel like I'm kinda wasting my time posting this, but if anyone wants it, have fun. If you just want to download the .cfg file and add it straight to your "scripts" folder, click -->here<--.

[SELECT ALL] Code:

//Credits to CiD's AFK Script        http://forum.cubers.net/thread-38.html (posted by Andrez)
//Note: I don't mean to steal script or claim I built this from scratch. This is credited to CiD's AFK script, whom I based my script off of, since his wasn't working for me, and it had excess coding.
//Usage: When you need to go afk, type "/afk". This will switch you to team spectator and add "-AFK" to your name, as well as printing to the console the afkmessage. When you want to stop being afk, type "/afk" again, this will remove the "-AFK", switch you to a team, and print a message announcing your return.
//Copyright or License: I don't really care if you modify this, just please credit both CiD's AFK Script and myself, Speedbomb00.
afksuf = "-AFK"
afkmessage = "is now afk."
returnmessage = "is no longer afk."
curafkmode = 0
alias afk [
if $arg1 [
if (= $curafkmode 0) [
oldname = $curname
me $afkmessage
name (concatword $oldname $afksuf)
curafkmode = 1
spectate] [
if $arg1 [
if (= $curafkmode 1) [
name $oldname
curafkmode = 0
me $returnmessage
spectate
]
]
]
]
]

[1Cap]

ty kcolspac10

[MykeGregory]

Could someone write me a script that gives me a 5 second countdown to respawn?
the normal countdown isn't there when your speccing someone.

[DeafieGamer]

Could someone write me a script that automatically place teamkiller in spect if TOSOK round is finished?

[Thrawn]

How to use universal delta and domodifier (How to use your mouse scroll wheel in scripts without rebinding the scroll wheel itself. This is especially useful if you have more than one script that you want to use with the mouse scroll wheel):

Overview:

Spoiler

Step 1.) You have to define delta_[x]_[y] , where [x] is either "game", "spect", or "edit", and [y] is some number (Note, it is important to pick a number that isn't in use, otherwise you will overwrite things you may not want to).  You may define the same delta number to do different things based on which mode you're in ("game" mode, spectate mode, or edit mode), or you may make them do the same regardless of what mode you are in.

Example:

[SELECT ALL] Code:

alias delta_game_77 [//Code set 1 goes here]
alias delta_edit_77 [//Code set 2 goes here]
alias delta_spect_77 [//Code set 3 goes here]

Versus:

[SELECT ALL] Code:

alias delta_game_77 [//Code set goes here]
alias delta_edit_77 delta_game_77
alias delta_spect_77 delta_game_77

(This just copies delta game 77 to edit and spect modes)


Step 2.) Bind a "Do Modifier" command to a key. Make sure it's the same number as your previous aliases!

Example:

[SELECT ALL] Code:

bind W [ domodifier 77 ]

Step 3.) Hold the key you bound, and scroll!

---

Usage:

Spoiler

When making the delta_[...] aliases, $arg1 will be the "input" (either 1 or -1 depending on which way you scroll the mouse wheel). For example

[SELECT ALL] Code:

alias delta_game_20 [ echo $arg1 ]
bind E [ domodifier 20 ]

Will echo 1 or -1 when you hold E and scroll

Real world examples:
Note: As of the time of this writing, the X key is bound by default in this way:

[SELECT ALL] Code:

editbind "X" " domodifier 3 "

which means that by default, the X key only does anything in edit mode. Also, by default (as of the time of this writing), there is only delta_edit_3 defined, not delta_game_3 nor delta_spect_3. This makes it a good choice for custom scripts that you want to use in game and spectate mode, but not in edit mode.

For example, a script I made to edit mouse sensitivity on-the-fly (Not that you'd necessarily want to do that):

[SELECT ALL] Code:

alias delta_game_3 [
   sensitivity (+f $sensitivity (*f 0.05 $arg1))
   echo (concat "Sensitivity =" $sensitivity)
]
alias delta_spect_3 delta_game_3

bind X [ domodifier 3 ]

This reads the 1 or -1 value from the scroll wheel ($arg1), multiplies it by 0.05, and then adds it to the current sensitivity (read from the $sensitivity variable), and then outputs the new sensitivity value. Note that I did not define delta_edit_3, as this is already bound by default. This adds functionality to the X key without interfering with it's useful functionality in edit mode


It is up to you whether you think it's best to add functionality to existing keys in this manner, or to instead bind things to unused keys

Note: At the time of this writing, the J key is not bound to anything by default.
Important! By default, only delta_spect_0 is defined; only delta_game_ 0 through 2 are defined; only delta_edit_ 0 through 11 are defined. delta_game_0 delta_edit_0 and delta_spect_0 are the functionalities used by the scroll wheel when no key is held down. If you overwrite these aliases, you will overwrite some default functionalities!

A script which allows you to scroll the console using the mousewheel:

[SELECT ALL] Code:

//You can change this to alter how quickly the mouse scrolls through the console
alias conskipmultiplier 3

alias delta_game_15 [ conskip (* $conskipmultiplier $arg1) ]
alias delta_spect_15 delta_game_15
alias delta_edit_15 delta_game 15

bind J [ domodifier 15 ]

[_DucK_]

Auto respaw (no need bind )
alias mapstartalways [sleep 100 [spaw]]
alias spaw [
if (= 1 (alive) ) [sleep 500 [spaw] ] [ echo [mort];sleep 5000 [attack;sleep 500 [spaw]] ]
]

Added menu checkbox
[cubescript]
alias respawx
alias mapstartalways [sleep 100 [spaw]]
alias spaw [
  if (= 1 (respawx) ) [ if (= 1 (alive) ) [sleep 500 [spaw]] [sleep 5000 [attack;sleep 500 [spaw]] ] ] [sleep 2000 [spaw] ]
]
[/cubescript]
((This goes to autoexec.cfg))
[cubescript]menuitemcheckbox [Auto respawn: ]     "$respawx"                     [ respawx = $arg1 ][/cubescript]
((This goes to whatever menu you would like to put this (I put in misc settings)))




UPDATE:::AFK SCRIPT + MENU:::
the afk script is by "TheKiller" (basic script).
I added the menu and the back online message

The system has
Menu (By me, Which allows the following: )
Enable/disable afk system
Enable/disable afk message
Enable/disable back online message
Set Suffix for your nick when AFK
Set time to AFK (in seconds, from 10 to 180)

Now, to install:
1) Add the following line under any menu you would like (my fav is under "gameplay")
[cubescript]menuitem [AFK settings...]                                     [ showmenu [AFK settings] ] [/cubescript]
2) Add this anywhere on menu config files (I added under gampley menu in menus_settings.cfg)
[cubescript]newmenu [AFK settings]

menuitemcheckbox   [Enable afk:            ]        "$afkenable"           [ afkenable = $arg1      ]
menuitemcheckbox   [Show afk message:      ]        "$afkshowmessage"      [ afkshowmessage = $arg1 ]
menuitemcheckbox   [Show online message:   ]        "$afkshowback"         [ afkshowback = $arg1    ]
menuitemtextinput  [Set afk name caption:  ]        "result $afkstr"       [ afkstr = $arg1         ]
menuitemtextinput  [Set afk message:       ]        "result $afkmessage"   [ afkmessage = $arg1     ]
menuitemtextinput  [Set online message:    ]        "result $backmessage"  [ backmessage = $arg1    ]
menuitemslider     [Set seconds until afk: ] 10 180 "$timeuntilafk" 10 []  [ timeuntilafk = $arg1   ][/cubescript]
3) Add this on the file "defaults.cfg"
[cubescript]afkstr = "|afk"
afkshowmessage = 0
afkshowback = 0
backmessage = "is available again."
afkmessage = "is no longer avilable."
timeuntilafk = 30
afkenable = 0[/cubescript]
4) Add this on autoexec.cfg file
[cubescript]
//AFK Script by TheKiller edited and menued by _DucK_

//DO NOT EDIT BELOW HERE
curafk = 0
afktime = 0
alias afk [
if (= ($afkenable) 1 ) [
if $arg1 [
if (= $curafk 0) [
oldname = $curname
name (concatword $oldname $afkstr)
curafk = 1
echo "You are now set to: AFK"
if $afkshowmessage [say (concat "AFK Message:" $oldname $afkmessage )]
]
] [
if $curafk [
name $oldname
curafk = 0
echo "You are now set to: ONLINE"
if $afkshowback [say (concat "AFK Message:" $oldname $backmessage )]
]
]
]
]
alias notafk [
if (= $afktime 0) [afkcheck]
afktime = 0
if (= $curafk 1) [afk 0]
]
alias afkcheck [
afktime = (+ $afktime 5)
if (= 2 (+ (> $afktime (* $timeuntilafk 1000)) (= $curafk 0))) [afk 1]
sleep 5 afkcheck
]
bind w [forward;notafk]
bind a [left;notafk]
bind s [backward;notafk]
bind d [right;notafk]
bind MOUSE4 [universaldelta  1;notafk] // this line was added by me
bind MOUSE5 [universaldelta -1;notafk] // this line was added by me
bind MOUSE1 [attack;notafk] // this was added by me
bind MOUSE2 [altaction;notafk] // by me
bind MOUSE3 [weapon;notafk] // by me[/cubescript]

*I am not quite sure if Thekiller is actually the author. if not, my apologies and credit goes to the original author

[Thrawn]

A script to show who the teamkillers are, and how many teamkills they have.
NOTE: Unintentional teamkills happen all the time! Please consider that some teamkills are accidental before kicking people!

[SELECT ALL] Code:

bind J [show_teamkillers]

persistidents 0

alias show_teamkillers [
  newmenu Teamkillers

  menuitem (concatword "| CN | " (c 3) "Teamkills" (c 5) " | " (c 2) "Name" (c 5) " |") -1
  alias _tklist []

  loop _cn 20 [
    if (isclient $_cn) [
      if (> (player $_cn tks) 0) [
        add2list _tklist $_cn
        menuitem (concatword "| " $_cn " | " (c 3) (player $_cn tks) (c 5) " | " (c 2) (player $_cn name)) -1
      ]
    ]
  ]
  if (= (listlen $_tklist) 0) [ menuitem (concatword (c 0) "No Teamkills detected! :D") -1 ]
 
  showmenu Teamkillers
 
  onrelease [closemenu Teamkillers; delmenu Teamkillers]
]

persistidents 1

[greatwhite]

@ Thrawn:
Nice! Useful. Thank you.

*Edit: Anyone have a script to automatically F2 any kick or ban vote against yourself?

[Mhtsos]

[SELECT ALL] Code:

persistidents 0
lolc = 0
checkinit onSpawn [ lolc = 0 ]
checkinit onKill [
if (&& (= $arg1 (player1 cn)) (!= $arg1 $arg2)) [
if (&& (curmodeattr team) (!= (player1 team) (player $arg2 team))) [
if ( = $lolc 0)[
hudecho (c 0)"You have slain an enemy"
lolc = 1
sleep 30000 [ lolc = 0 ]
][
if ( = $lolc 1 ) [
hudecho (c 0)"Double kill"
lolc = 2
sleep 30000 [ lolc = 0 ]
][
if ( = $lolc 2 ) [
hudecho (c 0)"Triple kill"
lolc = 3
sleep 30000 [ lolc = 0 ]
][
if ( = $lolc 3 ) [
hudecho (c 0)"Quadra kill"
lolc = 4
sleep 30000 [ lolc = 0 ]
][
if ( = $lolc 4 ) [
hudecho (c 0)"Penta kill"
lolc = 0
sleep 1000[ hudecho (c 1)"Ace!" ]
]
]
]
]
]
]
]
]
persistidents 1

Do you like my script??

[Mash]

I know there's already a script which makes you respawn on the same team as before but this one is event based... the idea is that you don't have to sleep for 500ms or something just to make sure the sleep time is larger than the ping so you actually went to spectate. Instead it switches back as soon as you're in spectate which results in a much faster respawn.

fireEvent was a more general approach so it also counts the milliseconds passed since waiting to fire but for sure you can't let two events race each other the second one will always kill the first one. As a hint though fireEvent is also really usefull for claiming and releasing admin.

[SELECT ALL] Code:

alias nop []

alias fireEvent [
 eventStatement = $arg1
 eventListener = $arg2
 if (! (&& (checkalias arg3) $arg3)) [
   eventStart = (millis)
 ]
 sleep 1 [
   if ($eventStatement) [
     ($eventListener (- (millis) $eventStart))
   ] [
     fireEvent $eventStatement $eventListener 1
   ]
 ]
]

checkinit mapstartalways [
   eventStart = 0
   eventStatement = 0
   eventListener = nop
]

alias isSpectate [
 return (= (curteam (player1 cn)) 4)
]
alias enterTeam [
 team $teamwish
 attack
]
alias respawn [
 if (! (&& (checkalias arg1) $arg1)) [
   if (= (curteam) 0) [
     teamwish = [CLA]
   ]
   if (= (curteam) 1) [
     teamwish = [RVSF]
   ]
 ]
 spectate
 fireEvent isSpectate enterTeam
]

And for sure the actual command created here is /respawn

[Céd|FR|]

I'm search without success a script for know automatically when my akimbo disappear , i have see the scipt by 888 but only the manual timer run for me.

[RaverZ]

Hello, I'd love to have auto vote auto change team thing.

Thanks to everyone who might be able to help me!

[Bukz]

[SELECT ALL] Code:

// Smooth sniper rifle scope zoom (using mouse wheel) script for AC 1.3+ by Bukz

ZOOM_SMOOTH = 1                         // set to 0 to disable smooth zooming
ZOOM_SMOOTH_MILLIS_BETWEEN_CHANGES = 15 // milliseconds between scopefov changes for smooth zooming
ZOOM_DEFAULT_SCOPEFOV = 50              // default scopefov for when you first scope in
ZOOM_SCOPEFOV_INCREMENT = 10            // change scopefov by this much on every tick of the mouse wheel

const isany [ bool = 0; looplist $arg2 ia [ if (strcmp $ia $arg1) [ bool = 1; break ] ]; result $bool ]
const validscopefov [ result (checkrange $arg1 5 60) ]

const doscope [
  if (! $numargs) [
    scopefov $ZOOM_DEFAULT_SCOPEFOV
    setscope 1
    onrelease [ setscope 0 ]
  ] [
    newfov = -1
    if (isany $arg1 [in 1 +]) [
      oper = -
      newfov = (- $scopefov $ZOOM_SCOPEFOV_INCREMENT)
      dif = (- $scopefov $newfov)
    ] [
      if (isany $arg1 [out 0 -]) [
        oper = +
        newfov = (+ $scopefov $ZOOM_SCOPEFOV_INCREMENT)
        dif = (- $newfov $scopefov)
      ]
    ]
    if (validscopefov $newfov) [
      if $ZOOM_SMOOTH [
        loop sf $dif [
          sleep (* $ZOOM_SMOOTH_MILLIS_BETWEEN_CHANGES $sf) [
            newfov = ($oper $scopefov 1)
            if (validscopefov $newfov) [ scopefov $newfov ]
          ]
        ]
      ] [ scopefov $newfov ]
    ]
  ]
]
altaction_5 = doscope
delta_game_0 = [
  if (&& (= (curweapon) 5) (player1 scoping)) [
    if (= $arg1 1) [ doscope + ] [ doscope - ]
  ] [
    if (= $arg1 1) [ shiftweapon 1 ] [ shiftweapon -1 ]
  ]
]

[Bukz]

Mouse sensitivity finder menu for AC 1.3+:

[SELECT ALL] Code:

// Sensitivity finder menu for AC 1.3+ by Bukz
// use /showmenu $BUKZ_SENS_FINDER_MENU_NAME or bind it to a key if you would like

const BUKZ_SENS_FINDER_MENU_NAME "Bukz's Sensitivity Finder"
const bukz_sens_finder_refreshMenu [ closemenu $BUKZ_SENS_FINDER_MENU_NAME; sleep 0 [ showmenu $BUKZ_SENS_FINDER_MENU_NAME ] ]
alias BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE 3.25 // should be less than 100 and greater than 0

const bukz_sens_finder_updateAliases [
  tempalias bukz_sens_finder_multiplier (divf $BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE 100.0)
  tempalias bukz_sens_finder_step (*f $sensitivity $bukz_sens_finder_multiplier)
]

const bukz_sens_finder_tryPercentage [
  if (! (&& (>f $arg1 0) (<f $arg1 100))) [
    echo "\f3CRITICAL ERROR: \f5alias \f2" (addpunct BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE 0) " \f5is not in the valid range. It should be \f3less than 100 \f5and \f0greater than 0"
    echo "\f1Current value: \f5" $BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE
  ] [
    BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE = $arg1
    echo "\f1Changed \f2BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE \f1to: \f5" $BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE
  ]
]

const bukz_sens_finder_trySens [
  if (checkrange $arg1 0.001 1000.0) [
    bukz_sens_finder_testSensitivity = $arg1
    sensitivity $bukz_sens_finder_testSensitivity
    echo "\f1Changed sensitivity to: \f5" $sensitivity
    bukz_sens_finder_updateAliases
    bukz_sens_finder_refreshMenu
  ] [ echo "\f3Error: \f5" $arg1 " must be less than 100 and greater than 0" ]
]

bukz_sens_finder_testSensitivity = $sensitivity
bukz_sens_finder_tryPercentage $BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE

newmenu $BUKZ_SENS_FINDER_MENU_NAME
menuinit [ menuinitselection 4; bukz_sens_finder_updateAliases ]
menuitem "" -1
menuitemtextinput "\f1Change sensitivity percentage: \f5" "$BUKZ_SENS_FINDER_SENSITIVITY_PERCENTAGE" [ bukz_sens_finder_tryPercentage $arg1 ]
menuitemgreyedout 1
menuitemtextinput "\f1Your current sensitivity is: \f5" "$sensitivity"
menuitemgreyedout 0
menuitem "" -1
menuitem "This sensitivity is \f3too low \f5for me." [ bukz_sens_finder_trySens (+f $sensitivity $bukz_sens_finder_step) ]
menuitem "This sensitivity is \f0too high \f5for me." [ bukz_sens_finder_trySens (-f $sensitivity $bukz_sens_finder_step) ]
menuitem "" -1
menuitem "          \f0[Save Current Sensitivity & Close]" [ alias bukz_sens_finder_idealSens $sensitivity; echo "\f1Your current sensitivity has been stored in alias \f2bukz_sens_finder_idealSens"; closemenu $BUKZ_SENS_FINDER_MENU_NAME ]
menuitem "                         \f1[Refresh]" [ bukz_sens_finder_refreshMenu ]
menuitem "                          \f3[Close]" [ closemenu $BUKZ_SENS_FINDER_MENU_NAME ]