V-Man Smooth Zoom

[V-Man]

Uh...
I couldn't find it on my computer, so I just redid it. XD

[SELECT ALL] Code:

// Smooth-zoom script, 1.1.0.4 redux by DES|V-Man; previous work by kirin and Gibstick.
// Bind "smoothzoom" to the key you wish to use for this purpose.

if (checkalias dfov) [] [alias dfov $fov]
if (checkalias zoominrate) [] [alias zoominrate 250]
if (checkalias zoomoutrate) [] [alias zoomoutrate 125]
if (checkalias zoomfov) [] [alias zoomfov 75]

alias zoomingin 0
alias zoomingout 0

alias smoothzoom [
alias zoominstarttime (millis)
alias zoomingin 1
zoominloop
onrelease [
alias zoomoutstarttime (millis)
alias zoomingout 1
zoomoutloop]]

alias zoominloop [
if $zoomingin [
  alias newfov (-f $fov (*f (-f $dfov $zoomfov) (divf (-f (millis) $zoominstarttime) $zoominrate)))
  if (>=f $newfov $zoomfov) [fov $newfov] [fov $zoomfov; alias zoomingin 0]
  sleep 0 [zoominloop]] []]

alias zoomoutloop [
if $zoomingout [
  alias newfov (+f $fov (*f (-f $dfov $zoomfov) (divf (-f (millis) $zoomoutstarttime) $zoomoutrate)))
  if (<=f $newfov $dfov) [fov $newfov] [fov $dfov; alias zoomingout 0]
sleep 0 [zoomoutloop]] []]

newmenu "Smooth-Zoom"
menuitemtextinput [Default FOV (where FOV rests): ] [result $dfov] [alias dfov $arg1] 3
menuitemtextinput [Zoomed FOV (extent to which FOV zooms): ] [result $zoomfov] [alias zoomfov $arg1] 3
menuitemtextinput [Zoom-in rate (higher is slower): ] [result $zoominrate] [alias zoominrate $arg1] 6
menuitemtextinput [Zoom-out rate (higher is slower): ] [result $zoomoutrate] [alias zoomoutrate $arg1] 6
menuitem [                Apply Now!                ] [closemenu]

alias smoothmenu [showmenu "Smooth-Zoom"]